Admin school counts page

app/core/Router.coffee

@@ -33,6 +33,7 @@ module.exports = class CocoRouter extends Backbone.Router
     'admin/design-elements': go('admin/DesignElementsView')
     'admin/files': go('admin/FilesView')
     'admin/analytics': go('admin/AnalyticsView')
+    'admin/school-counts': go('admin/SchoolCountsView')
     'admin/analytics/subscriptions': go('admin/AnalyticsSubscriptionsView')
     'admin/level-sessions': go('admin/LevelSessionsView')
     'admin/users': go('admin/UsersView')

app/templates/admin.jade

@@ -44,6 +44,8 @@ block content
     ul
       li
         a(href="/admin/analytics") Dashboard
+      li
+        a(href="/admin/school-counts") School Counts
       li
         a(href="/admin/analytics/subscriptions") Subscriptions
       li

app/templates/admin/school-counts.jade

@@ -0,0 +1,49 @@
+extends /templates/base
+
+//- DO NOT TRANSLATE
+
+block content
+
+  if !me.isAdmin()
+    div You must be logged in as an admin to view this page.
+
+  else
+    p CodeCombat is now in #{view.totalSchools} schools with #{view.totalStudents} students [and #{view.totalTeachers} teachers] [in #{view.totalStates} states]
+    p Students not attached to NCES data: #{view.untriagedStudents}
+    .small Teacher: owns a classroom or has a teacher role
+    .small Student: member of a classroom or has schoolName set
+    .small States, Districts, Schools are from NCES
+
+    h2 State Counts
+    if view.stateCounts
+      table.table.table-striped.table-condensed
+        tr
+          th State
+          th Districts
+          th Schools
+          th Teachers
+          th Students
+        each stateCount in view.stateCounts
+          tr
+            td= stateCount.state
+            td= stateCount.districts
+            td= stateCount.schools
+            td= stateCount.teachers
+            td= stateCount.students
+
+    h2 District Counts by State
+    if view.districtCounts
+      table.table.table-striped.table-condensed
+        tr
+          th State
+          th District
+          th Schools
+          th Teachers
+          th Students
+        each districtCount in view.districtCounts
+          tr
+            td= districtCount.state
+            td= districtCount.district
+            td= districtCount.schools
+            td= districtCount.teachers
+            td= districtCount.students

app/views/admin/SchoolCountsView.coffee

@@ -0,0 +1,144 @@
+RootView = require 'views/core/RootView'
+CocoCollection = require 'collections/CocoCollection'
+Classroom = require 'models/Classroom'
+TrialRequest = require 'models/TrialRequest'
+User = require 'models/User'
+
+# TODO: trim orphaned students: course instances != Single Player, hourOfCode != true
+# TODO: match anonymous trial requests with real users via email
+
+module.exports = class SchoolCountsView extends RootView
+  id: 'admin-school-counts-view'
+  template: require 'templates/admin/school-counts'
+
+  initialize: ->
+    return super() unless me.isAdmin()
+    @classrooms = new CocoCollection([], { url: "/db/classroom/-/users", model: Classroom })
+    @supermodel.loadCollection(@classrooms, 'classrooms', {cache: false})
+    @students = new CocoCollection([], { url: "/db/user/-/students", model: User })
+    @supermodel.loadCollection(@students, 'students', {cache: false})
+    @teachers = new CocoCollection([], { url: "/db/user/-/teachers", model: User })
+    @supermodel.loadCollection(@teachers, 'teachers', {cache: false})
+    @trialRequests = new CocoCollection([], { url: "/db/trial.request/-/users", model: TrialRequest })
+    @supermodel.loadCollection(@trialRequests, 'trial-requests', {cache: false})
+    super()
+
+  onLoaded: ->
+    return super() unless me.isAdmin()
+
+    console.log(new Date().toISOString(), 'onLoaded')
+
+    teacherMap = {} # Used to make sure teachers and students only counted once
+    studentMap = {} # Used to make sure teachers and students only counted once
+    teacherStudentMap = {} # Used to link students to their teacher locations
+    orphanedSchoolStudentMap = {} # Used to link student schoolName to teacher Nces data
+    countryStateDistrictSchoolCountsMap = {} # Data graph
+
+    console.log(new Date().toISOString(), 'Processing classrooms...')
+    for classroom in @classrooms.models
+      teacherID = classroom.get('ownerID')
+      teacherMap[teacherID] ?= {}
+      teacherMap[teacherID] = true
+      teacherStudentMap[teacherID] ?= {}
+      for studentID in classroom.get('members')
+        studentMap[studentID] = true
+        teacherStudentMap[teacherID][studentID] = true
+
+    console.log(new Date().toISOString(), 'Processing teachers...')
+    for teacher in @teachers.models
+      teacherMap[teacher.id] ?= {}
+      delete studentMap[teacher.id]
+
+    console.log(new Date().toISOString(), 'Processing students...')
+    for student in @students.models when not teacherMap[student.id]
+      schoolName = student.get('schoolName')
+      studentMap[student.id] = true
+      orphanedSchoolStudentMap[schoolName] ?= {}
+      orphanedSchoolStudentMap[schoolName][student.id] = true
+
+    console.log(new Date().toISOString(), 'Processing trial requests...')
+    # TODO: this step is crazy slow
+    orphanSchoolsMatched = 0
+    orphanStudentsMatched = 0
+    for trialRequest in @trialRequests.models
+      teacherID = trialRequest.get('applicant')
+      unless teacherMap[teacherID]
+        # console.log("Skipping non-teacher #{teacherID} trial request #{trialRequest.id}")
+        continue 
+      props = trialRequest.get('properties')
+      if props.nces_id and props.country and props.state
+        country = props.country
+        state = props.state
+        district = props.nces_district
+        school = props.nces_name
+        countryStateDistrictSchoolCountsMap[country] ?= {}
+        countryStateDistrictSchoolCountsMap[country][state] ?= {}
+        countryStateDistrictSchoolCountsMap[country][state][district] ?= {}
+        countryStateDistrictSchoolCountsMap[country][state][district][school] ?= {students: {}, teachers: {}}
+        countryStateDistrictSchoolCountsMap[country][state][district][school].teachers[teacherID] = true
+        for studentID, val of teacherStudentMap[teacherID]
+          countryStateDistrictSchoolCountsMap[country][state][district][school].students[studentID] = true
+        for orphanSchool, students of orphanedSchoolStudentMap
+          if school is orphanSchool or school.replace(/unified|elementary|high|district|#\d+|isd|unified district|school district/ig, '').trim() is orphanSchool.trim()
+            orphanSchoolsMatched++
+            for studentID, val of students
+              orphanStudentsMatched++
+              countryStateDistrictSchoolCountsMap[country][state][district][school].students[studentID] = true
+            delete orphanedSchoolStudentMap[school]
+    console.log(new Date().toISOString(), "#{orphanSchoolsMatched} orphanSchoolsMatched #{orphanStudentsMatched} orphanStudentsMatched")
+
+    console.log(new Date().toISOString(), 'Building graph...')
+    @totalSchools = 0
+    @totalStudents = 0
+    @totalTeachers = 0
+    @totalStates = 0
+    @stateCounts = []
+    stateCountsMap = {}
+    @districtCounts = []
+    for country, stateDistrictSchoolCountsMap of countryStateDistrictSchoolCountsMap
+      continue unless /usa/ig.test(country)
+      for state, districtSchoolCountsMap of stateDistrictSchoolCountsMap
+        @totalStates++
+        stateData = {state: state, districts: 0, schools: 0, students: 0, teachers: 0}
+        for district, schoolCountsMap of districtSchoolCountsMap
+          stateData.districts++
+          districtData = {state: state, district: district, schools: 0, students: 0, teachers: 0}
+          for school, counts of schoolCountsMap
+            studentCount = Object.keys(counts.students).length
+            teacherCount = Object.keys(counts.teachers).length
+            @totalSchools++
+            @totalStudents += studentCount
+            @totalTeachers += teacherCount
+            stateData.schools++
+            stateData.students += studentCount
+            stateData.teachers += teacherCount
+            districtData.schools++
+            districtData.students += studentCount
+            districtData.teachers += teacherCount
+          @districtCounts.push(districtData)
+        @stateCounts.push(stateData)
+        stateCountsMap[state] = stateData
+    @untriagedStudents = Object.keys(studentMap).length - @totalStudents
+
+    @stateCounts.sort (a, b) ->
+      return -1 if a.students > b.students
+      return 1 if a.students < b.students
+      return -1 if a.teachers > b.teachers
+      return 1 if a.teachers < b.teachers
+      return -1 if a.districts > b.districts
+      return 1 if a.districts < b.districts
+      b.state.localeCompare(a.state)
+    @districtCounts.sort (a, b) ->
+      if a.state isnt b.state
+        return -1 if stateCountsMap[a.state].students > stateCountsMap[b.state].students
+        return 1 if stateCountsMap[a.state].students < stateCountsMap[b.state].students
+        return -1 if stateCountsMap[a.state].teachers > stateCountsMap[b.state].teachers
+        return 1 if stateCountsMap[a.state].teachers < stateCountsMap[b.state].teachers
+        a.state.localeCompare(b.state)
+      else
+        return -1 if a.students > b.students
+        return 1 if a.students < b.students
+        return -1 if a.teachers > b.teachers
+        return 1 if a.teachers < b.teachers
+        a.district.localeCompare(b.district)
+    super()

server/middleware/classrooms.coffee

@@ -248,3 +248,8 @@ module.exports =
       sendwithus.api.send context, _.noop
     
     res.status(200).send({})
+
+  getUsers: wrap (req, res, next) ->
+    throw new errors.Unauthorized('You must be an administrator.') unless req.user?.isAdmin()
+    classrooms = yield Classroom.find().select('ownerID members').lean()
+    res.status(200).send(classrooms)

server/middleware/trial-requests.coffee

@@ -49,3 +49,8 @@ module.exports =
     trialRequests = yield TrialRequest.find({applicant: mongoose.Types.ObjectId(applicantID)})
     trialRequests = (tr.toObject({req: req}) for tr in trialRequests)
     res.status(200).send(trialRequests)
+
+  getUsers: wrap (req, res, next) ->
+    throw new errors.Unauthorized('You must be an administrator.') unless req.user?.isAdmin()
+    trialRequests = yield TrialRequest.find(status: {$ne: 'denied'}).select('applicant properties').lean()
+    res.status(200).send(trialRequests)

server/middleware/users.coffee

@@ -94,3 +94,14 @@ module.exports =
         verify_link: "http://codecombat.com/user/#{user._id}/verify/#{user.verificationCode(timestamp)}"
     sendwithus.api.send context, (err, result) ->
     res.status(200).send({})
+
+  getStudents: wrap (req, res, next) ->
+    throw new errors.Unauthorized('You must be an administrator.') unless req.user?.isAdmin()
+    students = yield User.find({$and: [{schoolName: {$exists: true}}, {schoolName: {$ne: ''}}, {anonymous: false}]}).select('schoolName').lean()
+    res.status(200).send(students)
+
+  getTeachers: wrap (req, res, next) ->
+    throw new errors.Unauthorized('You must be an administrator.') unless req.user?.isAdmin()
+    teacherRoles = ['teacher', 'technology coordinator', 'advisor', 'principal', 'superintendent', 'parent']
+    teachers = yield User.find(anonymous: false, role: {$in: teacherRoles}).select('').lean()
+    res.status(200).send(teachers)

server/routes/index.coffee

@@ -69,6 +69,7 @@ module.exports.setup = (app) ->
   app.post('/db/classroom/:classroomID/members/:memberID/reset-password', mw.classrooms.setStudentPassword)
   app.post('/db/classroom/:anything/members', mw.auth.checkLoggedIn(), mw.classrooms.join)
   app.get('/db/classroom/:handle', mw.auth.checkLoggedIn()) # TODO: Finish migrating route, adding now so 401 is returned
+  app.get('/db/classroom/-/users', mw.auth.checkHasPermission(['admin']), mw.classrooms.getUsers)
 
   CodeLog = require ('../models/CodeLog')
   app.post('/db/codelogs', mw.codelogs.post)
@@ -91,8 +92,9 @@ module.exports.setup = (app) ->
   app.put('/db/user/-/remain-teacher', mw.users.remainTeacher)
   app.post('/db/user/:userID/request-verify-email', mw.users.sendVerificationEmail)
   app.post('/db/user/:userID/verify/:verificationCode', mw.users.verifyEmailAddress) # TODO: Finalize URL scheme
-  
   app.get('/db/level/:handle/session', mw.auth.checkHasUser(), mw.levels.upsertSession)
+  app.get('/db/user/-/students', mw.auth.checkHasPermission(['admin']), mw.users.getStudents)
+  app.get('/db/user/-/teachers', mw.auth.checkHasPermission(['admin']), mw.users.getTeachers)
   
   app.get('/db/prepaid', mw.auth.checkLoggedIn(), mw.prepaids.fetchByCreator)
   app.post('/db/prepaid', mw.auth.checkHasPermission(['admin']), mw.prepaids.post)
@@ -105,5 +107,6 @@ module.exports.setup = (app) ->
   app.post('/db/trial.request', mw.trialRequests.post)
   app.get('/db/trial.request/:handle', mw.auth.checkHasPermission(['admin']), mw.rest.getByHandle(TrialRequest))
   app.put('/db/trial.request/:handle', mw.auth.checkHasPermission(['admin']), mw.trialRequests.put)
+  app.get('/db/trial.request/-/users', mw.auth.checkHasPermission(['admin']), mw.trialRequests.getUsers)
 
   app.get('/healthcheck', mw.healthcheck)