codecombat/app/lib/LocalMongo.coffee

LocalMongo = module.exports

# Checks whether func(l, r) is true for at least one value of left for at least one value of right
mapred = (left, right, func) ->
  _.reduce(left, ((result, singleLeft) ->
    result or (_.reduce (_.map right, (singleRight) -> func(singleLeft, singleRight)),
      ((intermediate, value) -> intermediate or value), false)), false)

doQuerySelector = (value, operatorObj) ->
  value = [value] unless _.isArray value # left hand can be an array too
  for operator, body of operatorObj
    body = [body] unless _.isArray body # right hand can be an array too
    switch operator
      when '$gt' then return false unless mapred value, body, (l, r) -> l > r
      when '$gte' then return false unless mapred value, body, (l, r) -> l >= r
      when '$lt' then return false unless mapred value, body, (l, r) -> l < r
      when '$lte' then return false unless mapred value, body, (l, r) -> l <= r
      when '$ne' then return false if mapred value, body, (l, r) -> l == r
      when '$in' then return false unless _.reduce value, ((result, val) -> result or val in body), false
      when '$nin' then return false if _.reduce value, ((result, val) -> result or val in body), false
  true


LocalMongo.doLogicalOperator = (target, operatorObj) ->
  for operator, body of operatorObj
    switch operator
      when '$or' then return false unless _.reduce body (res, query) -> res or matchesQuery target query, false
      when '$and' then return false unless _.reduce body (res, query) -> res and matchesQuery target query, true


LocalMongo.matchesQuery = (target, queryObj) =>
  for prop, query of queryObj
    return false unless prop of target
    if typeof query != 'object' or _.isArray query
      return false unless target[prop] == query or (query in target[prop] if _.isArray target[prop])
    else return false unless doQuerySelector(target[prop], query)
  true